Würde gerne wissen wie man Addons vollständig löscht, in diesm fall Altoholic.
Wenn ich Altoholic mit Twitch deinstalliere, dann im World of Warcraft Ordner nach sämtlichen Altoholic Datei-resten suche und lösche, dann wieder Altoholic installiere, sind sämtliche zuvor gescannte Charaktere und einstellungen noch vorhanden.
Ich weiss wenn ich den ganzen Cache und WTF Ordner lösche, dann auch garantiert alles gelöscht ist, aber ich möchte spezifisch nur Altoholic vollständig zurücksetzten ohne die einstellungen der anderen Addons anzufassen.
Wonach muss ich sonst noch suchen um sämtliche spuren von Altoholic zu löschen?
Um die gespeicherten Daten eines AddOns zu löschen, kann man entweder im Spiel entsprechende Befehle eingeben oder die Dateien bei beendetem WoW-Client manuell löschen.
Um alle Dateien von Altoholic zu löschen suchst du im Ordner ...\WTF\Account\<dein Accountname>\
nach Dateien, die folgende Namen enthalten:
Altoholic
DataStore
und löscht diese.
Alternativ kannst du eine Batch-Datei erstellen, die die Einstellungen aller nicht mehr vorhandenen AddOns löscht.
Bevor du ein deratiges Programm ausführst solltest du natürlich zur Sicherheit den WTF-Ordner sichern (z.B. als Archiv via 7zip).
Code:
@echo off
if not exist %~dp0WoW.exe exit
pushd %~dp0WTF\Account
del /s *.bak
del /s *.old
for /d %%i in (*) do (
if exist %%i\SavedVariables\ (
echo Account: %%i
for %%j in ("%%i\SavedVariables\*.lua") do (
echo %%~nj | findstr /r /i "^Blizzard_" > nul
if errorlevel 1 (
::echo GlobalSV: %%~nj
if not exist ..\..\Interface\AddOns\%%~nj\ (
echo delete global SVar: %%~nj
del "%%j"
)
)
)
for /d %%j in ("%%i\*") do (
echo checking folder: %%~nj
for /d %%k in ("%%j\*") do (
echo checking character: %%~nk
for %%l in ("%%k\SavedVariables\*.lua") do (
echo %%~nl | findstr /r /i "^Blizzard_" > nul
if errorlevel 1 (
::echo CharSV: %%~nl
if not exist ..\..\Interface\AddOns\%%~nl\ (
echo delete: %%~nl
del "%%l"
)
)
)
)
)
)
)
popd
pause