Makro Frage

Guides Interface, Addons & Makros
1

Hallo Community,
bräuchte Hilfe bei einem Makro, welches ich mir derzeit so zusammengebastelt habe.
#showtooltip
/castsequence [help] [target=mouseover,help,exists] Heilende Woge
/castsequence [harm] [target=mouseover,harm, nodead] Blitzschlag

Sinn dieses Makros war es das ich sowohl einen Angriff als auch einen Heal Skill in einem habe.
Das Makro funktioniert soweit ganz gut was ich aber sehr störend empfinde ist das mir der Tooltip wenn ich nichts anvisiert habe oder im Mouseover habe nur als ? angezeigt wird.

Ich hoffe mir kann jemand bei meinem Problem helfen

mfg

2

Das liegt daran, dass bei fehlendem Ziel auch kein Zauber gewirkt wird.

Am besten ist es, verknüpfte Bedingungen hinter den selben /cast-Befehl zu schreiben und eine Basisbedingung zu setzen.
In deinem Fall wäre das der Zauber Blitzschlag.

Außerdem ist der Befehl /castsequence hier unnötig, da du keine Sequenz sondern immer nur 1 expliziten Zauber wirken möchtest.

Beachte die Reihenfolge deiner Bedingungen!

Wenn du [help] vor [@mouseover] setzt, bedeutet dies, dass dein Ziel vor deinem Mouseover priorisiert wird.
Denn wenn keine target-Bedingung angegeben wird, wird @target benutzt.

Logischer wäre es umgekehrt:
Zauber auf mouseover, falls es freundlich ist, ansonsten auf das Ziel, sofern die Bedingung zutrifft.
also vor [@mouseover,help][help]


Hinweise zum Kürzen des Makros:

  • target= ist identisch mit @, aus target=mouseover kannst du @mouseover machen
  • help prüft, ob das angegebene Ziel freundlich ist, exists ist unnötig, da nur existende Ziele freundlich sein können (das gleiche gilt für feindliche Ziele via harm)

Dein Makro in Kurzform:

#showtooltip
/cast [@mouseover,help][help] Heilende Woge; [@mouseover,harm,nodead][] Blitzschlag

Die leere Bedingungsklammer [] am Ende ist gleichbedeutend mit /cast Blitzschlag bzw. /cast [@target] Blitzschlag.


Alternativ kannst du auch die Bedingung für den Tooltip direkt in der Tooltip-Anzeige setzen.

Beispiel hierfür:

#showtooltip [@mouseover,help][help] Heilende Woge; Blitzschlag
/cast [@mouseover,help][help,nodead] Heilende Woge; [@mouseover,harm,nodead][harm,nodead] Blitzschlag
2 Likes
3

Vielen vielen herzlichen Dank hat wunderbar funktioniert.

4

Grundsätzlich hat Shinizu ja schon soweit alles zu deinem spezifischen Makro gesagt, zusätzlich dazu würde ich den Hinweis zur Reihenfolge der Bedingungen aber noch etwas erweitern:

Aktuell hast du beide help-Bedingungen vor der ersten harm-Bedingung. Dadurch werden diese Bedingungen immer priorisiert behandelt und wenn du bspw. ein freundliches Ziel besitzt, wird die feindliche Mouseover-Bedingung überhaupt nicht erreicht.

Wenn das dein gewünschtes Verhalten ist, dann passt das Makro so, wenn du aber auch mit freundlichem Ziel per Mouseover Blitzschläge wirken können willst, dann müsste man die Reihenfolge darauf anpassen.

1 Like
5

Danke für den Hinweis das ist gut zu wissen :slight_smile:

6

Nochmal eine Bescheidene Frage, versuche gerade das hier umzusetzen mit den nomod befehl.
Aber es klappt wieder nicht :rofl:

ich möchte gerne wenn ich schift drücke die Kettenheilung wirken, wenn ich nichts drücke die Springflut und wenn ich einen Gegner anvisiere Lavaeruption.

Wäre nett wenn mir das noch mal jemand zusammenbasteln würde ich glaube ich bin zu blöd für solch komplexe Makros :innocent:

7

Im Prinzip ist das System relativ simpel:

  • Bedingungen stehen immer in eckigen Klammern.
  • Bedingungen, die gleichzeitig aktiv sein sollen, gehören mit einem Komma getrennt in die gleiche eckige Klammer.
  • Bedingungen werden immer von links nach rechts abgearbeitet.
  • Unterschiedliche Fähigkeiten in einem Befehl werden mit einem Semikolon getrennt.
  • Modifikatoren müssen in der englischen Bezeichnung angegeben werden

In deinem Fall wäre das also bspw. nur für das Ziel:

#showtooltip
/cast [help,mod:shift] Kettenheilung; [help] Springflut; Lavaeruption

Wirke Kettenheilung, wenn das Ziel freundlich ist und Umschalt gedrückt ist.
Ansonsten wirke Springflut, wenn das Ziel freundlich ist.
Ansonsten wirke Lavaeruption.

Möchtest du auch mit dem Mouseover spielen können, dann musst du überall einfach eine zusätzliche Klammer damit einfügen und dieses vor das normale Ziel setzen:

#showtooltip
/cast [@mouseover, help, mod:shift] [help,mod:shift] Kettenheilung; [@mouseover,help] [help] Springflut; [@mouseover,harm] [] Lavaeruption

Bei der Reihenfolge kommt es dann aber auch wieder darauf an, ob du auch Lavaeruption per Mouseover wirken können willst, wenn du ein freundliches Ziel hast. Wenn ja, dann müsste das weiter nach vorne gezogen werden, bspw. so:

#showtooltip
/cast [@mouseover, help, mod:shift] [help,mod:shift] Kettenheilung; [@mouseover,harm] Lavaeruption; [@mouseover,help] [help] Springflut; [] Lavaeruption
2 Likes
8

Hat geklappt Danke!
Und vielen Dank für die Tollen Erklärungen :slight_smile:

9

Wusste garnicht, dass man in der Zeile auch Bedingungen setzen kann :smiley:

Frage: Macht das Sinn? Wenn du einen Mob oder Spieler unter dem Mauszeiger hast, kannst du ja nicht gleichzeitig die Maus über dem Actionbutton haben um den Tooltip zu kriegen. Übersehe ich was?

10

Seit wann braucht man beim tooltip bedingungen?
bei mir passt sich #showtooltip immer der cast bedingung an.

11

In diesem Fall geht es mehr um das Icon, das umgeschalten wird.

Logischerweise funktioniert die mouseover-Bedingung für den Tooltip selbst nicht, wenn der Mauszeiger über der Aktionsleiste ist.
Aber das ist hier nicht relevant bzw. wird hier auch gar nicht benötigt.

Es gibt
#show, das die Icon-Anzeige steuert und
#showtooltip, das die Icon- und die Tooltip-anzeige steuert

Der Befehl nimmt verschiedene Informationen auf, vereinfacht:

Befehl Argument Beschreibung
#show spellname Anzeige des Icons des angebenen Zaubers
#show itemname Anzeige des Icons des angebenen Items
#show BagId slot Anzeige des Icons des jeweiligen Taschenplatzes
#show InvSlot Anzeige des Icons des jeweiligen Inventarplatzes
#show dynamische Anzeige des Icons, dessen Zauber/Item
die nachfolgenden Befehle als erstes ausführen würden

#showtooltip spellname Anzeige des Icons & Tooltip des angebenen Zaubers
#showtooltip itemname Anzeige des Icons & Tooltip des angebenen Items
#showtooltip BagId slot Anzeige des Icons & Tooltip des jeweiligen Taschenplatzes
#showtooltip InvSlot Anzeige des Icons & Tooltip des jeweiligen Inventarplatzes
#showtooltip dynamische Anzeige des Icons & Tooltip, dessen Zauber/Item
die nachfolgenden Befehle als erstes ausführen würden
2 Likes
12

Niemand schrieb, dass man die braucht sondern dass man sie benutzen kann.

Wenn man z.B. schreibt:

/cast [@target,help,nodead] Heilzauber; [@target,harm,nodead] Schadenszauber

verhindert man, dass das Makro versucht, auf tote oder nicht existente Ziele zu zaubern.
Würde man eine leere Klammer benutzen, um immer (außer bei freundlichen Zielen) den Schadenszauber zu wirken, würde man bei einem unzulässigen Ziel (neutral, tot, nicht vorhanden) eine Fehlermeldung (Text & Audio) erhalten.
Bei dem o.g. Makro nutzt man dann einfach

#show [@target,help,nodead] Heilzauber; Schadenszauber

für die Anzeige des Icons, damit bei fehlendem freundlichen & feindlichen Ziel das Icon des Schadenszaubers angezeigt wird, ein Druck des Makros aber keine Fehlerausgabe erzeugt.

Außerdem kannst du mit einer eigenen #show-Bedingung z.B. dafür sorgen, dass das Icon eines Zauber mit Cooldown dauerhaft angezeigt wird aber du bei Druck weiterhin einen anderen Zauber benutzt, z.B.

#show ZauberMitCD
/cast [mod:ctrl] ZauberMitCD; ZauberOhneCD
1 Like
13

Die letzte leere Klammer ist redundant, da ihr keine andere Bedingungsklammer vorsteht. :wink:
z.B.

#showtooltip
/cast [mod:shift,@mouseover,help][mod:shift,help] Kettenheilung; [@mouseover,harm] Lavaeruption; [@mouseover,help][help] Springflut; Lavaeruption
14

Genau. In dem Fall würde es reichen, #show + Bedingung zu machen, da es nur ums Icon geht.

Also so:

#show [@mouseover,help][help] Heilende Woge; Blitzschlag
/use [@mouseover,help][help] Heilende Woge; [@mouseover,harm,nodead] Blitzschlag

15

Ja, dann gibt es aber auch keinen Tooltip, wenn man mit der Maus auf dem Actionbutton ist.
Manche möchten das aber :wink:

Das erzeugt schließlich keine CPU-Mehrlast bis auf die bei der Anzeige des Tooltips.

Und der TE hatte das ja so benutzt, deswegen hatte ich es beibehalten.

In der letzten Klammer sollte eigentlich harm,nodead, dass hatte ich vergessen:

#showtooltip [@mouseover,help][help] Heilende Woge; Blitzschlag
/cast [@mouseover,help][help,nodead] Heilende Woge; [@mouseover,harm,nodead][harm,nodead] Blitzschlag
16

Den Tooltip gibt es doch sowieso nur für Blitzschlag, denn für den Heilende Woge Tooltip musst du ja mit der Maus über einem freundlichen Ziel sein. Aber du kannst nicht über einem freundlichen Ziel sein, wenn du für den Tooltip schon über der Aktionsleiste bist :smiley:

Vll. eher so?

#showtooltip [help] Heilende Woge; Blitzschlag
/cast [@mouseover,help][help,nodead] Heilende Woge; [@mouseover,harm,nodead][harm,nodead] Blitzschlag

17

Ha, natürlich - da habe ich die Klammer doch einfach aus dem vorherigen Makro übernommen und nicht mehr weiter nachgedacht. :smiley:

18

Dieses Thema wurde automatisch 180 Tage nach der letzten Antwort geschlossen. Es sind keine neuen Nachrichten mehr erlaubt.