Makro , Priorität, harm, mod

[Yoogy-eredar]

Hallo Community,

bräuchte ein Makro welches nach folgenden Prioritäten funktioniert: Mouseover>Target>shift @Player.

Bei Möglichkeit soll dann noch die Fähigkeit “Heal1” , wenn ein Gegner im Target ist auf Fähigkeit"DMG1" wechseln und aber auch, wenn die Maus dann über ein befreundetes Ziel geht auf Fähigkeit “Heal1” zurück wechseln.

Mit freundlichen Grüßen,
Yoogy

[Shinizu-dalvengyr (Shinizu)]

Dafür arbeitest du einfach die Bedingungen nacheinander, abhängig von der Priorität, ab.

In deinem Fall hast du 3 - 5 Ziele:

• Mouserover freundlich
• Mouseover feindlich
• Target freundlich
• Target feindlich
• Player

Die kursiven Ziele hast du nicht genannt, zur Vollständigkeit führe ich sie auf.

---

Da du deinen Selbstzauber per SHIFT wirken möchtest, können wir ihn einfach als ersten Befehl setzen, da diese Modifikator-Bedingung die strikteste ist und alle anderen Zauber keinen Modifikator benutzen.
[mod:shift,@player] Heal1

---

Beim Mouseover ergibt sich
[@mouseover,help,nodead] Heal1 für freundliche Mouseover-Ziele
[@mouseover,harm,nodead] DMG1 für feindliche Mouseover-Ziele
(die Bedingung für feindliche Mouseover-Ziele benötigst du anscheinend nicht, ich habe sie der Vollständigkeit halber gepostet)

---

Für das Target ergibt sich
[@target,help,nodead] Heal1 für freundliche Ziele
[@target,harm,nodead] DMG1 für feindliche Ziele
Da bei fehlender Ziel-Angabe immer auf @target geprüft wird, können wir das weiter einkürzen:
[help,nodead] Heal1 für freundliche Ziele
[harm,nodead] DMG1 für feindliche Ziele

---

Bei aufeinanderfolgenden identische Zaubern kannst du die Bedingungsklammern aneinander fügen.

Beispiel:
statt
/cast [mod:shift,@player] Heal1; [@mouseover,help,nodead] Heal1
schreibst du
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1

---

Eine Variante des Makros würde für
(bei Shift auf den Spieler > Heal1/DMG1 auf Mouseover > Heal1/DMG1 auf Target)
lauten:
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [@mouseover,harm,nodead] DMG1; [help,nodead] Heal1; [harm,nodead] DMG1

---

Willst du hingegen nur
(bei Shift auf den Spieler > Heal1 auf Mouseover > DMG1 auf Target),
dann wäre der Befehl
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [harm,nodead] DMG1

---

Damit das Zaubersymbol / Icon korrekt angezeigt wird, fügt man am Ende der Befehlskette eine leere Klammer bzw. einen Zauber ohne Bedingung ein oder modifiziert den Tooltip (die Profi-Variante).

Beispiel:
Simpel:

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [] DMG1

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; DMG1

Für das große Makro:

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [@mouseover,harm,nodead] DMG1; [help,nodead] Heal1; [] DMG1

#showtooltip
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [@mouseover,harm,nodead] DMG1; [help,nodead] Heal1; DMG1

Eleganter:

#showtooltip [mod:shift][@mouseover,help,nodead] Heal1; DMG1
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [harm,nodead] DMG1

#showtooltip [mod:shift][@mouseover,help,nodead] Heal1; [@mouseover,harm,nodead][] DMG1
/cast [mod:shift,@player][@mouseover,help,nodead] Heal1; [@mouseover,harm,nodead] DMG1; [help,nodead] Heal1; [harm,nodead] DMG1

[Dregnan-gorgonnash]

Bei der Prioritätenliste bin ich mir nicht sicher.
Ich tippe mal, dass es in die Richtung geht:
modifier:shift (player)>mouseover (harm oder help) > target (harm oder help)

#showtooltip
/cast [@player,mod:shift] Heal1;[@mouseover,harm,nodead] DMG1;[@mousover,nodead][help,nodead] Heal1;DMG1

@Shinizu Sicher das es notwendig ist in diesem Fall #showtooltip so komplex anzugehen, weil es ja eigentlich keinen Fall gibt wo ein Fragezeichen auftauchen würde?

[Yoogy-eredar]

Vielen Dank für die echt gute Erklärung, selten so gut erklärt bekommen! Danke