I had a problem with battlenet and all the blizzard suggested things including uninstalling battlenet but now that I’m trying to reinstall it, it keeps going to 32% then going all the way down to 0% then all the way up to 32% again then back to 0. What do I have to do to fix this? (Ps I did use again the blizzard suggested stuff like disable security, reinstall the app again and the whatever but still nothing)
Hi,
OK then try my script which will help you to repair Battle Net.
@echo off
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b)
echo Killing processes before starting...
echo.
taskkill /f /im Agent.exe /t
taskkill /f /im Battle.net* /t
echo.
echo Cleaning Windows temporary files...
echo.
timeout /t 3 >nul
:: cleaning Windows temporary files
if exist "%TEMP%" (
del /f /s /q "%TEMP%" 2>nul
for /f "tokens=*" %%D in ('dir /b /s /a:d "%TEMP%" 2^>nul') do rmdir /s /q "%%D" 2>nul
)
if exist "%ALLUSERSPROFILE%\TEMP" (
del /f /s /q "%ALLUSERSPROFILE%\TEMP" 2>nul
for /f "tokens=*" %%D in ('dir /b /s /a:d "%ALLUSERSPROFILE%\TEMP" 2^>nul') do rmdir /s /q "%%D" 2>nul
)
if exist "%SystemRoot%\TEMP" (
del /f /s /q "%SystemRoot%\TEMP" 2>nul
for /f "tokens=*" %%D in ('dir /b /s /a:d "%SystemRoot%\TEMP" 2^>nul') do rmdir /s /q "%%D" 2>nul
)
:: rem cleaning Battle.Net cache
echo.
echo Cleaning Battle Net...
echo.
timeout /t 2 >nul
del /f /q %USERPROFILE%\AppData\Local\Battle.net\*.*
rd /s /q "%USERPROFILE%\AppData\Local\Battle.net\Cache"
rd /s /q "%USERPROFILE%\AppData\Local\Battle.net\BrowserCache"
rd /s /q "%USERPROFILE%\AppData\Local\Battle.net\WidevineCdm"
rd /s /q "%USERPROFILE%\AppData\Local\Blizzard Entertainment"
rd /s /q "%ProgramData%\Blizzard Entertainment"
rd /s /q "%APPDATA%\Blizzard Entertainment"
cls
:: Asking if we repair the Agent
:ask_repair
color 0f
echo I can also repair the Battle.Net Agent, but this will force it to redownload and reinstall entirely.
echo You will most likely have to reconfigure the location of your games, but you will not have to redownload them.
echo.
set /p "FixAgent=Do you want to repair the Battle.net agent? (Y/N) : "
if /i "%FixAgent%"=="Y" (
rd /s /q "%ProgramData%\Battle.net\Agent"
echo.
color 2
echo Battle.net agent has been repaired.
echo.
goto end
) else if /i "%FixAgent%"=="N" (
echo.
color 7
echo Battle.net agent has not been repaired.
echo.
goto end
) else (
echo.
echo.
color 0c
echo Please enter "Y" or "N".
timeout /t 3 >nul
color 7
cls
goto ask_repair
)
:end
timeout /t 3 >nul
Then Save it to FixBnet.bat
Run it in admin mode
Yo! Firstly lemme say I’m really sorry for the late reply (I kinda figured maybe the forums was a lost cause, glad to see I was wrong!) Mind if I ask where I should put the script? Like should I go into Battle.net setup then into “Edit with Notepad++”?