All in one arena123 / BG / All content CC macros

[Slavez-ravencrest]

Hello.

I made an all in one solution, to make the arena 1,2 and 3 keybinds work as target, focus and mousover keybinds instead whenever you are not in the arena. This is the only solution I’ve found that works around the battlegrounds arena123 targets.
It requires many actionbutton slots, and many macro slots so it might not be suited for everyone. The following example is done for warlocks counter spell, making it also dispell party 1 and 2 if imp is used instead of felhunter.

For each arena target you will need 3 macros. The first which will be keybinded looks as follows:

#showtooltip Command Demon
/click [@party3,noexists] MultiBarRightButton4
/click [@party3,exists] MultiBarRightButton10

Then on the action button assigned on line 1, you put the arena macro (This needs an [@Arena] conditional):

#showtooltip Command Demon
/stopcasting
/cast [@arena3,exists,harm] Command Demon; [@party2,help] Command Demon; [@mouseover,exists] Command Demon;

On the second action button you put your macro for non arena:

#showtooltip
/cast [@mouseover] Command Demon

You would of course replace the macros with your own spells, and the action buttons with the one you are using yourself.

For example if I want Fear for arena 123 in the arena, but for target/focus/mouseover outside I will have the following macro sets:
Set 1:

#showtooltip Fear
/click [@party3,noexists] MultiBarRightButton1
/click [@party3,exists] MultiBarRightButton7

#showtooltip Fear
/cast [@arena1,exists] Fear; Fear

#showtooltip
/cast Fear

Set 2:

#showtooltip Fear
/click [@party3,noexists] MultiBarRightButton2
/click [@party3,exists] MultiBarRightButton8

#showtooltip Fear
/cast [@arena2,exists] Fear; [@focus] Fear

#showtooltip
/cast [@focus] Fear

Set 3:

#showtooltip Fear
/click [@party3,noexists] MultiBarRightButton3
/click [@party3,exists] MultiBarRightButton9

#showtooltip Fear
/cast [@arena3,exists] Fear; [@mouseover] Fear

#showtooltip
/cast [@mouseover] Fear

If you know a better way to make macros work for both arenas, BGs, PvE content and open world. Please let me know. This requires 9 macros and actionbar slots per spell.

[Elvenbane-kazzak]

You can optimize you click macros like this:

#showtooltip Command Demon
/click [@party3,exists] MultiBarRightButton10; MultiBarRightButton4

And cast macros like this:

#showtooltip
/cqs
/stopcasting
/cast [@arena3,harm,nodead] [@party2,help,nodead] [@mouseover,exists,nodead] [] Command Demon

That said, you can eliminate the need for both click and cast macros if you just do this:

#showtooltip
/cast [@arena1,exists]; [@mouseover,exist,nodead] [] Command Demon
/cast [@arena3,harm,nodead] [@party2,help,nodead] [@mouseover,exists,nodead] [] Command Demon

The top cast checks if you’re in an arena (@arena1,exists) and if you are does nothing, otherwise it does your non-arena cast. The 2nd cast does all your arena targeting. Outside of arena the GCD from the first cast blocks the 2nd cast so this is only a useful technique for abilities that are on the GCD or that go on CD once used.

In this example you could also use the pet:imp condition as a filter and eliminate the double cast logic.

#showtooltip
/cast [@arena3,harm,nodead] [pet:imp,@party2,help,nodead] [@mouseover,exists,nodead] [] Command Demon

For things like Fear that aren’t using @party# conditions just use condition fallbacks, no need for anything fancier.

#showtooltip
/cast [@arena1,harm] [] Fear

#showtooltip
/cast [@arena2,harm] [@focus,harm,nodead] [] Fear

#showtooltip
/cast [@arena3,harm] [@mouseover,harm,nodead] [] Fear

[Slavez-ravencrest]

@Elvenbane-kazzak

For things like Fear that aren’t using @party# conditions just use condition fallbacks, no need for anything fancier.

#showtooltip
/cast [@arena1,harm] [] Fear

#showtooltip
/cast [@arena2,harm] [@focus,harm,nodead] [] Fear

#showtooltip
/cast [@arena3,harm] [@mouseover,harm,nodead] [] Fear

The problem with this solution is that battlegrounds have arena targets too. Which breaks these macros whenever you enter e.g. kotmogu, wsg etc.

Hence the click macros that checks wether party 3 exists or not.

Also you are forced into a raid group inside an arena, so [group:raid] won’t do either. Also I’ve tried the /cast ; parameter, but it gives an error when the first cast parameter is empty.