Any smart macro warrior who might be able to see a workaround to this macro stancedance+[mod:ctrl]

[Smurrisha-ravencrest]

So I am trying to cram as many spells as possible into 1 actionbar button! So far it has worked great on ALL other classes, but now that I’ve come to my warrior I have run into a major because I also have to stance dance as the only class in game.
The issue is mainly that I have to stance dance a lot I can’t seem to make the modifier work while ALSO including the correct stance for it, the way I can with a simple macro… to put it simple:

This is the NEW macro I now use e,g,
#showtooltip
/cast [nomod] Sunder Armor(Rank 5); [mod:ctrl] Taunt;

before I used the simple OLD macro:
#showtooltip Taunt
/cast Taunt
/cast Defensive Stance

both work as intended but here is where it gets TRICKY! since I now have them both Sunder and Taunt in 1 botton with the NEW macro and I got the NEW macro on the actionbar in ALL stances, however I only want Defensive Stance to trigger when I use the [ctrl:mod] Taunt and NOT when I use [nomod] Sunder Armor

is there ANY way to make it possible? the only solution I can see this working in would be to be able to call a macro within a macro which I dunno if possible (and if so without having to install an addon for it).

in other words the macro I would like to have created is both OLDD and NEW macro merged together so it would work like this:

#showtooltip
/cast [nomod] Sunder Armor(Rank 5); [mod:ctrl] Taunt /cast Defensive Stance;

so it ONLY cast defensive stance when I use the mod:ctrl for taunt and NOT when I cast sunderarmor…

Anyone who know a workaround about this?

I got the same issue when I wanna use
#showtooltip
/cast [nomod] Charge(Rank 3); [mod:ctrl] Intercept(Rank 3);

and have it be in the correct stance to cast it as well…

[Whoman-razorgore]

#showtooltip
/cast [nomod] Sunder Armor(Rank 5);
/cast [mod:ctrl,stance:2] Taunt;
/cast [mod:ctrl,nostance:2] Defensive Stance;

Is that what you’re after?

I’d recommend putting all stance dances on 1 button, and mocking blow/ taunt / zerker rage (depending on stance) and your 30 min CDs (depending on stance + mod ctrl) on 1 button if you’re looking to save space.

Also:
/cast [stance:1] Charge; [stance:3] Intercept;

Also a tip of you don’t have tactical master you can also ;
/Cast charge;
/Cast defensive stance;
This will charge, swap stance,and due to spellbatching you keep the charge rage.

[Saranthir-ten-storms]

Judging from your information, would the 30min cd macro look like this?:
/cast [stance:1] Retalliation; [stance:2] Shield Wall; [stance:3] Recklessness;
If so, would it cast the relevant CD based on my current stance?

[Whoman-razorgore]

Yes. For example if you’re in battle stance it will run like this;

Stance 1 - battle stance - ok - cast retaliation
Stance 2 - defensive stance - no - skip
Stance 3 - berserker stance - no - skip

[Saranthir-ten-storms]

Interesting, didn’t realise I could run macros this way, certainly opens up additional possibilities for me to clean up my action bars. Far too many spells crammed on screen

[Smurrisha-ravencrest]

@Whoman-razorgore

#showtooltip
/cast [nomod] Sunder Armor(Rank 5);
/cast [mod:ctrl,stance:2] Taunt;
/cast [mod:ctrl,nostance:2] Defensive Stance;

Is that what you’re after?

That is EXCATLY what I was after! Except I would like it to show only taunt and sunder armor #showtooltips and not defensive stance tooltip

[Whoman-razorgore]

Try this;
#showtooltip
/cast [nomod] Sunder Armor(Rank 5);
/cast [mod:ctrl] Taunt;
/cast [mod:ctrl,nostance:2] Defensive Stance;

Note, if you’re not in def stance, it’ll say "you can’t cast that’ and then push you into def stance, and clicking it again will taunt. I’ll link some of my Macros below.

[Smurrisha-ravencrest]

@Whoman-razorgore

Note, if you’re not in def stance, it’ll say "you can’t cast that’ and then push you into def stance, and clicking it again will taunt. I’ll link some of my Macros below.

You are the man! However I tried reversing the order in the macro! cause before I had to click 2 times to get taunt to activate (as you mentioned) but if I reversed the order it now taunt right away in 1st click with:

#showtooltip
/cast [nomod] Sunder Armor(Rank 5);
/cast [mod:ctrl,nostance:2] Defensive Stance;
/cast [mod:ctrl] Taunt;
/cancelaura Blessing of Salvation
/cancelaura Greater Blessing of Salvation

HOWEVER the tooltip for taunt will now only show when already in defensive stance else it with show defensive stance tooltip once again

[Whoman-razorgore]

Yea, the #showtooltip will show the first spell that will be cast. Either Taunt first and it shows taunt, or Defensive Stance if you have that first.

Here are some I use;

Stance Specific spells + CDs

#showtooltip
/cast [stance:1,mod:ctrl] Retaliation;
/cast [stance:2,mod:ctrl] Shield Wall;
/cast [stance:3,mod:ctrl] Recklessness;
/cast [stance:1] Overpower;
/cast [stance:2] Shield Bash;
/cast [stance:3] Pummel;

All stances accessible from 1 key.

/cast [mod:ctrl] Berserker Stance;
/cast [mod:ctrl,Stance:3] Battle Stance;
/cast [stance:1,nomod:ctrl] Defensive Stance;
/cast [stance:2,nomod:ctrl] Battle Stance;
/cast [stance:3,nomod:ctrl] Defensive Stance;

Taunts

#showtooltip
/cast [mod:ctrl] Challenging Shout;
/cast [stance:1] Mocking Blow;
/cast [stance:2] Taunt;
/cast [stance:3] Berserker Rage;

[Smurrisha-ravencrest]

well I just worked a little with the macro u gave me before so now it’s

#showtooltip
/cast [nomod] Sunder Armor;
/cast [mod:ctrl,nostance:2] Defensive Stance;
/cast [mod:ctrl] Taunt;
/cast [mod:alt,nostance:2] Battle Stance;
/cast [mod:alt] Mocking Blow;
/cast [mod:shift] Challenging Shout;

only thing that sucks is the lack of tooltips that doesn’t always follow
gonna work a little on the others as well I can get them fit to my liking and playstyle

[Whoman-razorgore]

That looks good.

I also use TellMeWhen, which shows 4 abilities and their CD so I can keep track of the important ones (taunt, shield slam, mocking blow, zerker rage).

[Smurrisha-ravencrest]

@Whoman-razorgore

I also use TellMeWhen, which shows 4 abilities and their CD so I can keep track of the important ones (taunt, shield slam, mocking blow, zerker rage).

I was planning on using something like that too!

however can u see what I’m doing wrong here… I liked the macro u posted earlier

@Saranthir-ten-storms

/cast [stance:1] Retalliation; [stance:2] Shield Wall; [stance:3] Recklessness;

However I wanted to add last stand to it so I made the following macro:
#showtooltip
/cast [nomod] Last Stand; [mod:ctrl][stance:1] Retaliation;
/cast [nomod] Last Stand; [mod:ctrl][stance:2] Shield Wall;
/cast [nomod] Last Stand; [mod:ctrl][stance:3] Recklessness;

(i’ve tried multiple variations) it works as intended with 1 problem… instead of working with the ctrl modifier it only works when I use shift… despite not having shift in the macro… and I can’t figure out what the issue is. If I click ctrl it will ALWAYS show retaliation in any stance… but if I shift… it shows the correct spell

[Whoman-razorgore]

@Smurrisha-ravencrest

/cast [nomod] Last Stand; [mod:ctrl][stance:1] Retaliation;
/cast [nomod] Last Stand; [mod:ctrl][stance:2] Shield Wall;
/cast [nomod] Last

Here it is I think;
#showtooltip
/cast [nomod] Last stand;
/cast [stance:1,mod:ctrl] Retaliation;
/cast [stance:2,mod:ctrl] Shield Wall;
/cast [stance:3,mod:ctrl] Recklessness

You put all conditionals with one set of brackets separated by commas.

If your macros get big, you can also just use a single /cast sequence like so;

#showtooltip
/cast [nomod] Last stand; [stance:1,mod:ctrl] Retaliation; [stance:2,mod:ctrl] Shield Wall;[stance:3,mod:ctrl] Recklessness;

[Smurrisha-ravencrest]

Well I tried reversing the macro so it now looked like this

#showtooltip
/cast [nomod] Last Stand; [mod:shift][stance:1] Retaliation;
/cast [nomod] Last Stand; [mod:shift][stance:2] Shield Wall;
/cast [nomod] Last Stand; [mod:shift][stance:3] Recklessness;

NOW it work as intended when I click ctrl… it makes no f**king sense… when I use shift it will show retaliation in ALL stances (despite shift being the modifier) when I click ctrl it will now show the buff depending on the stance as it should
makes no sense whatsoever, but it works so I’m fine

anyways can you perhaps see a fix to this macro:

#showtooltip
/cast [nomod] Conjured Sparkling Water;Conjured Sweet Roll
/cast [mod:ctrl] Morning Glory Dew; [mod:alt] Roasted Quail;
/use Conjured Sweet Roll
/use Conjured Sparkling Water
/cast Find Herbs
/cast Find Minerals

the macro completely ignore the modificer… and I want to to show either water (on manabased heroes) and food (on rogues/warriors)…
problem is when I use a modifier it always show sweet rolls (unless I don’t do anything then it shows water)

[Whoman-razorgore]

@Smurrisha-ravencrest

#showtooltip
/cast [nomod] Last Stand; [mod:shift][stance:1] Retaliation;
/cast [nomod] Last Stand; [mod:shift][stance:2] Shield Wall;
/cast [nomod] Last Stand; [mod:shift][stance:3] Recklessness;

Here are the variants of that Macro;
#showtooltip
/cast [nomod] Last Stand; [mod:shift,stance:1] Retaliation;
/cast [mod:shift,stance:2] Shield Wall;
/cast [mod:shift,stance:3] Recklessness;

#showtooltip
/cast [nomod] Last Stand;
/cast [mod:shift,stance:1] Retaliation;
/cast [mod:shift,stance:2] Shield Wall;
/cast [mod:shift,stance:3] Recklessness;

#showtooltip
/cast [nomod] Last Stand; [mod:shift,stance:1] Retaliation; [mod:shift,stance:2] Shield Wall; [mod:shift,stance:3] Recklessness;

[Sortella-stonespine]

#showtooltip [stance:1] Retaliation; [stance:2] Shield Wall; [stance:3] Recklessness
/cast [stance:1] Retaliation; [stance:2] Shield Wall; [stance:3] Recklessness;

[Saranthir-ten-storms]

@Smurrisha-ravencrest

#showtooltip
/cast [nomod] Conjured Sparkling Water;Conjured Sweet Roll
/cast [mod:ctrl] Morning Glory Dew; [mod:alt] Roasted Quail;
/use Conjured Sweet Roll
/use Conjured Sparkling Water
/cast Find Herbs
/cast Find Minerals

I’d like more info on this.
I have a macro for nomod, mod:shift and mod:ctrl but it completely ignores the 3rd modifers.