ВВЕДЕНИЕ
Сложные гайды натолкнули меня на мысль, поделиться опытом. Дать новичкам быстрое решение проблем и поделиться интересными находками.
ВНИМАНИЕ: Статья сделана для классического клиента. Возможно в вашей версии WOW, некоторые задачи, будут иметь другое решение. НО прочитав эту статью, вы справитесь.
ОРУЖИЕ
Первое с чем сталкиваются на прокачке, это как брать оружие в разные руки. У каждого слота на персонаже есть свой номер:
https://images3.wikia.nocookie.net/wowwiki/images/a/ae/InventorySlots.jpg
/equipslot 16 Секира
/equipslot 17 Короткий кинжал
Слот 16 это правая рука, его нужно указывать первым для избежания косяков.
Если у вас 2 одинаковые одноручки, могут возникнуть проблемы при разных условиях. Предлагаю не простое, но стабильное решение:
/equipslot [mod:alt] 16 Секира
/stopmacro [mod:alt]
/castsequence reset=2 Секира
/equipslot 17 Секира
Для экипировки одинаковых оружий, вам в ЛЮБОМ СЛУЧАЕ придётся нажимать ДВАЖДЫ. Этот макрос привязан ко времени. При нажатии он экипирует ОСНОВНУЮ РУКУ (правую), и в течении 2 секунд, при повторных нажатиях, будет менять левую.
Тут тоже возникают проблемы, если у вас в левой руке уже экипировано это оружие, основная не меняется. По этому [mod:alt] позволяет принудительно экипировать правую руку.
Так же советую ознакомиться с ЭТОЙ ТЕМОЙ.
Для двуручки (в классике) слоты писать ненужно:
/equip Клеймор
Для ДВУХ двуручных оружий, используйте варианты описанные выше. (для следующих версий wow).
АВТОАТАКА
Часто люди не могут начать атаку по тому, что не хватает ярости. В классике авто атака не начинается сама, вам нужно либо использовать атакующую способность, либо использовать способность Атака, которая так же прекращает атаку при повторном нажатии.
Команда /startattack начинает атаку и не прекращает её при повторном нажатии. Её желательно вшивать во все макросы, на воине так точно. Так же необходимо в большинство макросов писать /dismount что бы спешиваться и #showtooltip для отображения способности.
Если у вас есть аддон спешивающий вас, то /dismount вам не нужен.
В БК и Личе спешивание срабатывает само. Но комбинация /dismount и /startattack позволяет вам гарантированно спешиться и начать атаку, а не просто смотреть на цель.
Таким образом мы получаем шапку, наличие которой не обязательно, но очень желательно:
/dismount
/startattack
#showtooltip
ПРОСТЫЕ МАКРОСЫ
Начнём с самых простых, но необходимых вещей.
/dismount
/startattack
#showtooltip
/cast Раскол брони
Раскол брони используется из ЛЮБОЙ СТОЙКИ, не все это знают. Вам не нужно переключать стойку, что бы кинуть его на босса или толстого моба. Да он создаёт агро, но в не Оборонительной стойки, 1-2 раскола не повлияют на вашу угрозу и возможно сохранят 5 стаков на боссе.
МЕНЯЕМ СТОЙКИ
В меняющих стойку макросах, смена стойки идёт первой способностью. По этому #showtooltip будет показывать именно смену стойки. Что бы это исправить, нужно после #showtooltip поставить пробел и написать нужную нам способность, перезарядку которой мы хотим видеть на иконке:
/dismount
/startattack
#showtooltip Превосходство
/cast Боевая стойка
/cast Превосходство
Советую сделать подобные на: Разоружение, Возмездие, Безрассудство, Вихрь, Ярость берсерка.
Макросы меняющие стойки желательно выносить с переключающейся панели.
ГЕРОИК и РАССЕКАЮЩИЙ
На прокачке, особенно с медленным оружием, бывает хочется отменить Удар героя, т.к. он тратит ярость и не набирает новую.
/dismount
/startattack
#showtooltip
/cast Удар героя
/stopcasting [mod:alt]
Тут alt выключает следующий удар героя, но авто атака продолжается.
В место alt можно указать shift или ctrl, или вообще [mod:alt/ctrl].
СТРЕЛЬБА
Макрос для рог и варов.
/dismount
/startattack
#showtooltip
/cast [worn:метательное] Бросок; [worn:лук] Выстрел из лука; [worn:огнестрельное] Выстрел из ружья; [worn:арбалет] Выстрел из арбалета
В БК и Личе работает иначе:
/dismount
/startattack
#showtooltip
/cast [worn:метательное оружие] Бросок; Выстрел
Тут не нужно ничего менять, здесь указаны именно типы оружия. Выносим на панель и стреляем в не зависимости от экипированного типа оружия дальнего боя.
СБИВ КАСТА
Макрос на сбив каста становится актуален с получением Зуботычины:
/dismount
/startattack
#showtooltip [equipped:щит] Удар щитом; Зуботычина
/cast [noequipped:щит,nostance:3] Стойка берсерка
/cast [stance:3] Зуботычина
/cast [equipped:щит,nostance:3] Удар щитом; Зуботычина
Тут как и в макросе на стрельбу, не нужно ничего переписывать. Макрос в зависимости от вашей стойки и вида вооружения сам выбирает то, чем ему лучше сбить каст. Работает одним нажатием.
До получения Зуботычины сбивать каст не просто, нужно:
- Переключиться в Оборонительную стойку
- Набрать 10 ярости
- Взять щит
- Выждать ПЕРЕЗАРЯДКУ в 0.5 сек
- Нажать Удар щитом.
К сожалению это единственный способ сбивать каст до Зуботычины:
/dismount
/startattack
#showtooltip Удар щитом
/equipslot 16 Короткий кинжал
/equipslot 17 Каплевидный щит
/cast Оборонительная стойка
/cast Удар щитом
ГЛУХАЯ ОБОРОНА
Тут то же самое, после переключения на щит она заставляет выждать кд в 0.5 секунд:
Без щита Глухая оборона не нажимается. Но после активации, щит можно снять, баф останется.
/dismount
/startattack
#showtooltip Глухая оборона
/equipslot 16 Короткий кинжал
/equipslot 17 Каплевидный щит
/cast Оборонительная стойка
/cast Глухая оборона
БЛОК ЩИТОМ
С блоком другая история, у способности Блок щитом СВОЁ кд ни с чем не связанное, по этому переключение в Оборонительную стойку, надевание Щита и способность Блок щитом используются моментально. Советую всем, спасает при срыве босса и позволяет быстро перейти из дамагера в режим танка, если босс не страшнее Ониксии.
/dismount
/startattack
#showtooltip Блок щитом
/equipslot 16 Короткий кинжал
/equipslot 17 Каплевидный щит
/cast Оборонительная стойка
/cast Блок щитом
КАЗНЬ
Казалось бы что тут мудрить, но пока я делал этот макрос я нашёл БАГ в стойках. По этому пришлось намудрить с формой:
/dismount
/startattack
#showtooltip Казнь
/cast [stance:1/3] Казнь
/stopmacro [stance:1/3]
/cast Боевая стойка
/cast Казнь
Всё работает одним нажатием. В Боевой стойке, Казнь не меняет стойку, в Стойке берсерка тоже не меняет, из оборонительной переходит именно в Боевую стойку.
Советую делать макрос на Подрезание сухожилий по этому примеру.
ПРОВАКАЦИЯ и ДРАЗНЯЩИЙ УДАР
Из за того-же самого БАГА, и тут пришлось исхитриться, сам макрос на Таунт прост и идеален:
/cast Оборонительная стойка
/cast Провокация
Но если вы не Фури-прот, вам открывается возможность использовать Дразнящий удар, если Провакация ушла в сопротивление:
/cast Боевая стойка
/cast Дразнящий удар
Получилось всё укомплектовать в одну кнопку:
/dismount
/startattack
#showtooltip [mod:alt] Дразнящий удар; Провокация
/cast [mod:alt] Боевая стойка
/cast [mod:alt] Дразнящий удар
/stopmacro [mod:alt]
/cast Оборонительная стойка
/cast Провокация
РЫВОК и ПЕРЕХВАТ
Есть классический макрос на Рывок и Перехват, который у большинства воинов:
/dismount
#showtooltip [combat] Перехват; Рывок
/cast [nocombat] Боевая стойка
/cast [nocombat] Рывок
/cast [combat] Стойка берсерка
/cast [combat] Перехват
А что если у вас Рывок на перезарядке и вы не в бою? А что если у вас много ярости в Стойке берсерка? А что если вам именно сей час нужно дать оглушение на 3 секунды?:
/dismount
#showtooltip [mod:alt] Перехват; [combat] Перехват; Рывок
/cast [mod:alt] Стойка берсерка
/cast [mod:alt] Перехват
/stopmacro [mod:alt]
/cast [nocombat] Боевая стойка
/cast [nocombat] Рывок
/cast [combat] Стойка берсерка
/cast [combat] Перехват
Тут добавлен блок, позволяющий принудительно использовать Перехват через alt.
Я пробовал привязать Перехват к перезарядке Рывка, но у меня не вышло. Если знаете как это сделать пишите в комментариях.
ПАРА СОВЕТОВ
- При выборе иконки для макроса, оставляйте вопросик. Он будет принимать изображение способности, указанной после #showtooltip
- В Лич Кинге, появляется Вихрь клинков. Что бы его прервать, используйте /cancelaura Вихрь клинков.
- К Устрашающий крик можно добавить /stopattack что бы случайно не выбить врага из страха.
ПОСЛЕСЛОВИЕ
Это основные макросы для воина в вов классик, которые я считаю оптимизируют процесс игры. Я постарался дать готовые варианты и дать инструменты с примерами для создания макросов. Надеюсь вышло наглядно. Пробуйте, делайте, тестируйте.
Буду рад любым комментариям.
Если захотите ознакомиться подробнее с командами в макросах, вам СЮДА:
https://forum.wowcircle.net/showthread.php?t=2010
ТЕГИ
Макросы для воина вов классик, Русские макросы для воина, Гайд по макросам, Warrior macros classic wow, Макрос на рывок, Макрос на сбив каста. Макросы вов классик 2020, Classic guide to warriors macros, Макросы для вара, Макросы на вара, макросы для воина 3.3.5, макросы для воина Лич кинг, макросы для воина вов бк.